FP Laboratory 4

Functions working with lists

Implement following functions:

• Create a function that takes first n elements of the list.

take' :: Int -> [a] -> [a]

*Main> take' 2 [1,2,3]
[1,2]

take' :: Int -> [a] -> [a]
take' 0 _ = []
take' _ [] = []
take' n (x:xs) = x: take' (n-1) xs

• Create a function that takes the remaining list after the first n elements.

drop' :: Int -> [a] -> [a]

*Main> drop' 2 [1,2,3]
[3]

drop' :: Int -> [a] -> [a]
drop' 0 x = x
drop' _ [] = []
drop' n (_:xs) = drop' (n-1) xs

• Create a function that find the smallest element in the list. Consider input restrictions.

minimum' :: [a] -> a -- Is this right?

*Main> minimum' [1,3,4,0]
0

minimum' :: Ord a => [a] -> a 
minimum' [x] = x
minimum' (x:y:z) | x < y = minimum' (x:z)
                 | otherwise = minimum' (y:z)

• Find all integer divisors of a given number.

divisors :: Int -> [Int]

*Main> divisors 32  
[1,2,4,8,16,32]

divisors :: Int -> [Int]
divisors n = tmp n where
  tmp 0 = []
  tmp x | n `mod` x == 0 = x: tmp (x-1)
        | otherwise = tmp (x-1)

divisors' :: Int -> [Int]
divisors' n =  filter (\x -> n `mod` x == 0) [1..n] 

divisors'' :: Int -> [Int]
divisors'' n =  [x | x<-[1..n], n `mod` x == 0]

Functions working with lists and tuples

Implement following functions:

• Create a function that merge two lists into one list of tuples.

zipThem:: [a] -> [b] -> [(a,b)]

*Main> zipThem [1,2,3] "ABCD"
[(1,'A'),(2,'B'),(3,'C')]

zipThem:: [a] -> [b] -> [(a,b)]
zipThem (x:xs) (y:ys) = (x,y) : zipThem xs ys
zipThem _ _ = []

• Create a function that compute Cartesian product of two vectors.

dotProduct :: [a] -> [b] -> [(a,b)]

*Main> dotProduct [1..4] "ABC"
[(1,'A'),(1,'B'),(1,'C'),(2,'A'),(2,'B'),(2,'C'),(3,'A'),(3,'B'),(3,'C'),(4,'A'),(4,'B'),(4,'C')]

dotProduct :: [a] -> [b] -> [(a,b)]
dotProduct [] _ = []
dotProduct (x:xs) ys = tmp ys ++ dotProduct xs ys where
  tmp [] = []
  tmp (b:bs) = (x,b) : tmp bs

dotProduct' :: [a] -> [b] -> [(a,b)]  
dotProduct' xs ys = [(x,y)|x<-xs, y<-ys]

dotProduct'' :: [a] -> [b] -> [(a,b)]
dotProduct'' x y = 
  zip (concat (map (replicate (length y)) x))
                     (concat (replicate (length x) y))

• Create a function that computes n-th number in the Fibonacci sequence. The function should use tuples in the solution.

fibonacci :: Int -> Int

*Main> fibonacci 12
144

fibonacci :: Int -> Int
fibonacci n = fst (tmp n) where
  fibStep (a,b) = (b,a+b)
  tmp 0 = (0,1)
  tmp x = fibStep (tmp (x-1))

High-order functions

• Create a function that takes a string and converts all characters to upper case letters.

allToUpper :: String -> String

*Main> allToUpper "aAbc"
"AABC"

import Data.Char

allToUpper :: String -> String
allToUpper xs = [toUpper x |x<-xs]                     

allToUpper' :: String -> String
allToUpper' xs = map toUpper xs

• Implement the quicksort algorithm. As a pivot use always the first element in the list. For dividing the list, use the function filter.

quicksort :: (Ord a) => [a] -> [a]

*Main> filter (<5) [1..10]
[1,2,3,4]

*Main> quicksort [1,5,3,7,9,5,2,1]
[1,1,2,3,5,5,7,9]

quicksort :: (Ord a) => [a] -> [a]
quicksort [] = []
quicksort (x:xs) = let lp = filter (< x) xs
                       rp = filter (>= x) xs
                   in quicksort lp ++ [x] ++ quicksort rp

Additional exercises

• Create a function that removes the first occurrence of a given element from a list.

removeOne :: Eq a => [a] -> [a]

*Main> removeOne 4 [1,4,6,8,4,5,4,7]
[1,6,8,4,5,4,7]
*Main> removeOne 'e' "Ahoj"
"Ahoj"

• Create a function that removes all occurrences of a given element from a list.

removeAll :: Eq a => [a] -> [a]

*Main> removeAll 4 [1,4,6,8,4,5,4,7]
[1,6,8,5,7]
*Main> removeAll 'e' "Ahoj"
"Ahoj"

• Create your own implementation of the replicate function.

replicate' :: Int -> a -> [a]

*Main> replicate' 4 8 
[8,8,8,8]

• Create function alternate, which interleaves two lists into one, alternating between elements taken from the first list and elements from the second.

alternate :: [a] -> [a] -> [a]

*Main> alternate [1,2,3] [4,5,6]
[1,4,2,5,3,6]
*Main> alternate [1,2] [4,5,6]
[1,4,2,5,6]
*Main> alternate [1,2,3] [4]
[1,4,2,3]
*Main> alternate [1,2,3] []
[1,2,3]

• Use filter to create a non-recursive function that takes a list of integers as input and returns a list of those that are even and greater than 7.

filterEvenGt7 :: [Int] -> [Int]

*Main> filterEvenGt7 [1,2,6,9,10,3,12,8]
[10,12,8]
*Main> filterEvenGt7 [5,2,6,19,129]
[]